home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / CRS / crs53.d81 / 28may87s.pma / CXDISK.ASM < prev    next >
Assembly Source File  |  1979-12-31  |  35KB  |  1,778 lines
  1.  
  2.  
  3.  
  4. ;
  5. ;    *****************************************
  6. ;    *                    *
  7. ;    *    Commodore Disk    Controller    *
  8. ;    *    Module for CP/M 3.0 BIOS    *
  9. ;    *                    *
  10. ;    *****************************************
  11. ;
  12. ;
  13. ;
  14.     title 'CXDISK   Commodore C-128 Disk Controller    15 Apr 86'
  15.  
  16.  
  17.  
  18.  
  19. ; CP/M 3 Disk definition macros
  20.  
  21.     maclib    cpm3
  22.  
  23.     maclib    z80
  24.  
  25. ; C-128 system equates
  26.  
  27.     maclib    cxequ
  28.  
  29.     page
  30.  
  31. ; Disk drive dispatching tables for linked BIOS
  32.  
  33.     public    cmdsk0,cmdsk1,cmdsk2,cmdsk3,cmdsk4
  34.  
  35. ; System Control Block variables
  36.     extrn    @ermde        ; BDOS error mode
  37.  
  38. ; Utility routines in standard BIOS
  39.     extrn    ?wboot        ; warm boot vector
  40.     extrn    ?pmsg        ; print message @<HL> up to 00
  41.                 ; saves <BC> & <DE>
  42.     extrn    ?pdec        ; print binary number in <HL> from 0 to 65535
  43.     extrn    ?pderr        ; print BIOS disk error header
  44.     extrn    ?conin,?cono    ; con in and out
  45.     extrn    ?const        ; get console status
  46.     extrn    ?sctrn        ; sector translation routine
  47.     extrn    @covec
  48.  
  49. ;    status line calls
  50.  
  51.     extrn    ?save,?recov,?stat
  52.  
  53. ; System function call
  54.     extrn    ?kyscn
  55.     extrn    ?fun65
  56.     extrn    ?bank
  57.     extrn    ?di$int
  58.  
  59.     public    ?dskst
  60.     public    ?dkmov
  61.     extrn    ?stat,@st40
  62.  
  63.     page
  64. ;
  65. ; Initialization entry point.
  66. ; called for first time initialization.
  67. ;
  68.     DSEG
  69. init$154X:
  70.     xra    a
  71.     sta    fast
  72.     lxi    h,MFM$table
  73.     shld    MFM$tbl$ptr
  74.     ret
  75.  
  76.  
  77.     page
  78. ;
  79. ; This entry is called when a logical drive is about to
  80. ;  be logged into for the purpose of density and type determination.
  81. ;  It may adjust the parameters contained in the disk
  82. ;  parameter header pointed to by <DE>
  83. ;
  84.     DSEG
  85. ;
  86. ;    if disk type GCR or drive type 1541 or 1581(reports as GCR)
  87. ;       if sector size is 256 bytes
  88. ;          if 1st sector has 'CBM' (1st 3 bytes)
  89. ;             if last byte = -1 (0FFh)
  90. ;                set C128 double sided
  91. ;             else
  92. ;                set C128 single sided
  93. ;             endif
  94. ;          else
  95. ;             set C64 type
  96. ;          endif
  97. ;       else  (512 byte sector size)
  98. ;          set C1581 type
  99. ;       endif
  100. ;    else (must be MFM)
  101. ;       TEST MFM
  102. ;    endif
  103. ;
  104. login$154X:
  105.     call    get$drv$info    ; set the drive to check (DPH$pointer set)
  106.  
  107.     mvi    a,vic$test
  108.                 ; ***** add code to reset 1581 drive *****
  109.     call    ?fun65
  110.     mov    b,a
  111.     ani    0ch
  112.     cpi    0ch        ; fast drive ?
  113.     jrz    commodore$type    ; no, must be 1541 type
  114.     mov    a,b        ; yes, is a 1571 or 1581
  115.     rlc            ; MSB=1 if NON-Commodore disk 
  116.     jrc    MFM$type    ; 1571 NON-Commodore disk is MFM type
  117.  
  118.     page
  119. ;
  120. ;    Commodore Type disk is a disk that is in GCR format (1571)
  121. ;    Or Standard Commodore format for 1581 (Has a Commodore dir track)
  122. ;
  123. commodore$type:
  124.     lhld    DPH$pointer
  125.     dcx    h
  126.   if    use$1581
  127.     mov    a,b        ; get the status byte
  128.     ani    30h        ; save only the sector size info
  129.     cpi    20h        ; 512 byte sectors?
  130.     jrnz    set$15x1$type    ; no, set up as 1571 or 1541
  131.                 ; yes, set 1581 type drive
  132. ;
  133. ;
  134. ;
  135. set$1581$type:
  136.     mvi    m,dsk$1581    ; yes, set up as 1581 double sided
  137.     lxi    d,dpb$1581 
  138.     jr    set$dpb$only
  139.  
  140.   endif
  141.  
  142. set$15x1$type:
  143.     mvi    m,dsk$c64
  144.     lxi    d,dpb$c64$cpm    ; set DPB to C64
  145.     call    set$dpb$only
  146.  
  147.     xra    a
  148.     sta    vic$sect    ; set track 1 sector 0 (1st sector
  149.     inr    a        ; on the disk)
  150.     sta    vic$trk
  151.  
  152.     lxi    h,@buffer
  153.     shld    local$DMA    ; move DMA pointer to disk buffer
  154.     call    login$rd
  155.     ana    a        ; read error ?
  156.     rnz            ; yes, just return
  157.  
  158.     RCALL    FR$check$CBM
  159.     rnz            ; return if not 'CBM'
  160.                 ; A=0FFh if double sided
  161.     inr    a
  162.     lhld    DPH$pointer
  163.     dcx    h        ; does not affect flags
  164.     mvi    m,dsk$c128
  165.  
  166.     lxi    d,dpb$c128$SS
  167.     jrnz    set$dpb$only
  168.  
  169.     lxi    d,dpb$c128$DS
  170.  
  171.     page
  172. ;
  173. ;
  174. ;
  175. set$dpb$only:
  176.     lxi    b,0        ; set sector translation to zero
  177. set$format:
  178.     lhld    DPH$pointer
  179.     mov    m,c
  180.     inx    h
  181.     mov    m,b        ; install sector translation
  182.     lxi    b,25-1        ; ofset to DPB
  183.     dad    b        ; HL points to DPB now
  184.     lxi    b,17        ; dpb size
  185.     xchg            ; move to DPB location
  186.     ldir
  187.     ret
  188.  
  189.     page
  190. ;
  191. ;    TEST MFM()
  192. ;    save number bytes/sector
  193. ;       if double sided
  194. ;          mark two sided
  195. ;       endif
  196. ;       find start and end sector numbers
  197. ;       scan table of disk for match (if more then 1 match ask user) 
  198. ;
  199. MFM$type:
  200.     mvi    c,01100000b
  201.     ana    c            ; A = status(trk1) shifted left 1 
  202.     push    psw            ; save in case bad query
  203.     push    b            ; save BC
  204.  
  205.     call    get$max$num$B        ; used to set the pointer only
  206.     mov    b,m            ; get size, and disk lock flag
  207.     inx    h
  208.     mov    a,m
  209.     inx    h
  210.     mov    h,m            ; get last MFM$mactch$ptr
  211.     mov    l,a
  212.     mov    a,b            ; get lock flag in A
  213.     ani    80h            ; lock bit set ?
  214.     sta    lock$flag        ;   (save old lock status)
  215.     shld    last$match        ; save last match pointer
  216.     jrz    not$$locked$entry    ; yes, then set same disk type
  217. ; set$locked$entry
  218.     xra    a
  219.     sta    lock$flag
  220.     mvi    c,0B0h
  221.     lda    vic$data        ; get sector size info
  222.     ana    c
  223.     mov    b,a            ; save disk sector size info
  224.     xchg                ; save HL
  225.     lhld    DPH$pointer
  226.     dcx    h
  227.     mov    a,c
  228.     ana    m            ; get old disk sector size
  229.     cmp    b            ; are they the same?
  230.     jrnz    not$locked$entry    ; no, then unlock disk anyway
  231.  
  232.     xchg                ; get last match pointer (in DE)
  233.     pop    psw            ; yes, remove two data elements 
  234.     pop    psw            ; ..save on stack
  235.     jr    set$this$entry
  236.  
  237. not$locked$entry:
  238.     lxi    h,MFM$match$tbl        ; clear Match table
  239.     shld    MFM$cur$ptr
  240.     lxi    d,MFM$match$tbl+1
  241.     mvi    m,0
  242.     lxi    b,(MFM$tbl$entries*2)-1+1+1    ; table, offset and count
  243.     ldir
  244.     mvi    a,4
  245.     sta    vic$trk            ; do query on track 4
  246.     mvi    a,vic$query
  247.     call    ?fun65
  248.     pop    b            ; recover BC
  249.     ani    0eh            ; query error ?
  250.     jrnz    query$error        ; yes, use only bits 5 and 6 
  251.     lda    @buffer            ; get trk 4 status
  252.     mov    b,a            ; save in B
  253.     ani    0eh            ; trk 4 status error ?
  254.     jrnz    query$error        ; yes, use only bits 5 and 6
  255.     mov    a,b            ; recover B (trk 4 status)
  256.     add    a            ; shift left
  257.     ana    c            ; mask sector size bits
  258.     mov    b,a
  259.     pop    psw            ; get trk 1 sector size bits
  260.     cmp    b            ; same as trk 4 sector size?
  261.     mvi    c,01111111b
  262.     jrz    trk$1$trk$4        ; yes, (then test for mult format)
  263.     mvi    a,80h            ; set MSB to mean mult format
  264.     add    b            ; ..(track 0 different sector size
  265.                     ; ..then track 4) 
  266.     mov    b,a            ; save in B
  267.     mvi    c,11111111b
  268. trk$1$trk$4:
  269.     lda    @buffer+1        ; get number of sectors/track
  270.     sui    4            ; remove 4 to extend the range
  271.     add    a            ; shift    left
  272.     add    b            ; combine with rest of mask
  273.     mov    b,a            ; save in B for now
  274.  
  275.     lda    @buffer+3        ; minimum sector number
  276.     add    b            ; add in start sector #
  277.     push    psw            ; save on stack for a moment
  278.  
  279. query$error:
  280.     pop    psw            ; get value to match 
  281.     ana    c            ; test only those bits in the mask
  282.  
  283.     lhld    MFM$tbl$ptr
  284.     mvi    b,MFM$tbl$entries
  285. check$next:
  286.     push    b            ; save BC for a moment
  287.     mov    b,a            ; move compare value to 
  288.     mov    a,m            ; get type info
  289.     ana    c            ; test only the good info
  290.     cmp    b            ; match the current type byte
  291.     mov    a,b            ;   (recover A)
  292.     pop    b            ;   (recover BC)
  293.     jrnz    not$found        ; no, do not queue data
  294.                     ; yes queue table entry address
  295.  
  296.     xchg                ; save adr in DE
  297.     lhld    MFM$cur$ptr
  298.     mov    m,e
  299.     inx    h
  300.     mov    m,d
  301.     inx    h
  302.     shld    MFM$cur$ptr
  303.     lxi    h,MFM$count
  304.     inr    m            ; add one to counter
  305.     xchg
  306.  
  307.     page
  308. ;
  309. ;
  310. not$found:
  311.     lxi    d,32            ; table entry size
  312.     dad    d
  313.     djnz    check$next
  314.  
  315.     lda    MFM$count        ; number of matches in table 
  316.     ana    a            ; test for zero
  317.     jz    tell$user$no$entry    ; none, tell the user 
  318.  
  319.     dcr    a            ; only one ?
  320.     jrnz    user$select        ; no, go check with user (which one)
  321.     lhld    MFM$match$tbl        ; yes, use the only one found
  322.  
  323. ;
  324. ;    install data from pointer in HL
  325. ;
  326. set$this$entry:
  327.     push    h        ; save table pointer
  328.     inx    h
  329.     mov    a,m        ; get type info. 
  330.     xchg            ; save table address in DE
  331.     lhld    DPH$pointer
  332.     dcx    h
  333.     mov    m,a        ; save type code
  334.     xchg            ; get table adr to HL
  335.     inx    h        ; HL points to sector translation table 
  336.     mov    c,m        ; ..zero if none
  337.     inx    h
  338.     mov    b,m
  339.     inx    h        ; HL points to DPB
  340.     xchg            ; DE points to DPB (HL trash)
  341.     call    set$format
  342.     mov    b,m        ; get the number of sect/trk from MFM table
  343.     lda    lock$flag    ; get the current lock flag value
  344.     ora    b        ; combine with sect/trk
  345.     xchg            ; HL=to adr,  DE=from adr
  346.     mov    m,a        ; install sect/trk and lock flag
  347.     pop    d        ; recover table pointer
  348.     inx    h
  349.     mov    m,e
  350.     inx    h
  351.     mov    m,d        ; save MFM table pointer at end of DPH
  352.     ret
  353.  
  354.     page
  355. ;
  356. ;    let the user select the Disk type (s)he wants
  357. ;
  358. user$select:
  359.     inr    a            ; number of entries to try to match
  360.     mov    b,a            ; set in B as loop count
  361.     lhld    last$match        ; get value to match with
  362.     mov    d,h
  363.     mov    e,l            ; last match pointer is in DE
  364.  
  365.     lxi    h,MFM$match$tbl
  366.     shld    MFM$cur$ptr
  367.     mvi    c,0            ; start offset at zero
  368.  
  369. try$next$format:
  370.     mov    a,e
  371.     cmp    m
  372.     inx    h
  373.     jrnz    not$last$match
  374.     mov    a,d
  375.     cmp    m
  376.     jrnz    not$last$match
  377. ;
  378. ; match, set pointer
  379. ;
  380.     mov    a,c            ; get offset in A
  381.     push    psw
  382.     call    save$dsk$window
  383.     pop    psw
  384.     jr    set$offset
  385.  
  386. not$last$match:
  387.     inx    h            ; each pointer uses two bytes 
  388.     inr    c            ; advance the index
  389.     djnz    try$next$format        ; test for more, loop if so
  390.  
  391.     call    save$dsk$window
  392.  
  393.     lhld    MFM$cur$ptr
  394. user$loop:
  395.     mov    e,m            ; HL=(MFM$cur$ptr)
  396.     inx    h
  397.     mov    d,m
  398.     lxi    h,22            ; offset to NAME field
  399.     dad    d            ; point to Disk name
  400.     call    dsk$window$old
  401.  
  402. dsk$user$sel$wait:
  403.     call    ?kyscn
  404.     inr    b            ; test for key pressed
  405.     jrz    dsk$user$sel$wait
  406.     dcr    b            ; adjust back
  407.     mov    a,b            ; move matrix position to A
  408.     cpi    SF$exit
  409.     jrnz    CK$dsk$user$rt
  410.  
  411.     mov    a,c
  412.     ani    4            ; control key down ?
  413.     jrz    no$cntr$key        ; no, don't lock this selection
  414.     mvi    a,80h            ; yes, lock disk type to this drive
  415. no$cntr$key:
  416.     sta    lock$flag        ;
  417.     call    dsk$window$remove
  418.     lhld    MFM$cur$ptr
  419.     mov    e,m
  420.     inx    h
  421.     mov    d,m
  422.     xchg
  423.     jr    set$this$entry
  424.  
  425.     page
  426. ;
  427. ;
  428. ;
  429. CK$dsk$user$rt:
  430.     cpi    SF$right        ;
  431.     jrnz    CK$dsk$user$lf
  432.  
  433. ; move window down
  434.     lda    MFM$count        ; get number of items in list
  435.     mov    b,a            ; save in B
  436.     lda    MFM$offset        ; get current position
  437.     inr    a            ; advance position
  438.     cmp    b            ; at last position ? (n-1+1 =count)
  439.     jrnz    set$offset        ; no, then use A as new position
  440.     xra    a            ; yes, move back to start
  441.     jr    set$offset
  442.     
  443. CK$dsk$user$lf:
  444.     cpi    SF$left            ;
  445.     jrnz    dsk$user$sel$wait
  446.  
  447. ; move window up
  448.     lda    MFM$offset
  449.     dcr    a            ; back up offset (under flow?)
  450.     jp    set$offset        ; result positive, jump
  451.     lda    MFM$count        ; get last item number
  452.     dcr    a            ; pointer is 0 to n-1 (not 1 to n)
  453. set$offset:
  454.     sta    MFM$offset        ; set new list offset
  455.     inr    a            ; add one to adjust for DCR below
  456.     lxi    h,MFM$match$tbl        ; set to the beginning
  457.  
  458. adjust$dsk$loop:
  459.     shld    MFM$cur$ptr        ; set pointer here !
  460.     dcr    a            ; at offset yet?
  461.     jrz    user$loop        ; yes, go display name
  462.     inx    h
  463.     inx    h
  464.     jr    adjust$dsk$loop
  465.  
  466.     page
  467. ;
  468. ;
  469. ;
  470. tell$user$no$entry:
  471.     lda    vic$data        ; get disk test status
  472.     ani    0b0h            ; save only sector size and MFM flag
  473.     lhld    DPH$pointer
  474.     dcx    h
  475.     mov    m,a            ; set disk size and Type0 (MFM)
  476.  
  477.     lxi    h,dsk$window*256+buff$pos
  478.     lxi    d,no$dsk$msg
  479. disp$msg$DE$HL:
  480.     call    dsk$window$new
  481. dsk$no$entry$wait:
  482.     call    ?kyscn
  483.     inr    b
  484.     jrz    dsk$no$entry$wait
  485.     dcr    b
  486.     mov    a,b
  487.     cpi    SF$exit
  488.     jrnz    dsk$no$entry$wait
  489. ;    jr    dsk$window$remove
  490.  
  491.     page
  492. ;
  493. ;
  494. ;
  495. dsk$window$remove:
  496.     lhld    window$info
  497.     mov    b,h
  498.     mov    c,l
  499.     jmp    ?recov
  500. ;
  501. ;
  502. ;
  503. save$dsk$window:
  504.     lxi    h,dsk$window*256+buff$pos    ; H=size l=pos
  505.     shld    window$info
  506.     mov    b,h
  507.     mov    c,l
  508.     jmp    ?save
  509. ;
  510. ;
  511. ;
  512. dsk$window$new:
  513.     shld    window$info
  514.     xchg
  515.     mov    b,d
  516.     mov    c,e
  517.     push    h
  518.     call    ?save
  519.     pop    h
  520.  
  521. dsk$window$old:
  522.     lda    window$info        ; get start index
  523.     inr    a
  524.     mov    c,a            ; place in C
  525.  
  526. dsk$out$next:
  527.     push    h
  528.     lhld    window$info
  529.     mov    a,h
  530.     add    l            ; compute max index (start+size)
  531.     dcr    a            ; ..less 1
  532.     pop    h
  533.     cmp    c
  534.     rz    
  535.     mov    b,m
  536.     call    dsk$B$out
  537.     inx    h
  538.     jr    dsk$out$next
  539.  
  540. ;
  541. ;
  542. ;
  543. dsk$B$out:
  544.     mvi    a,01000000b            ; set reverse video attr
  545.     push    b
  546.     push    h
  547.     call    ?stat                ; display space
  548.     pop    h
  549.     pop    b                ; recover count
  550.     inr    c
  551.     ret
  552.  
  553.     page
  554. ;
  555. ; disk READ and WRITE entry points.
  556. ; These entries are called with the following arguments:
  557. ;    relative drive number in @rdrv (8 bits)
  558. ;    absolute drive number in @adrv (8 bits)
  559. ;    disk transfer address in @dma (16 bits)
  560. ;    disk transfer bank    in @dbnk (8 bits)
  561. ;    disk track address    in @trk (16 bits)
  562. ;    disk sector address    in @sect (16 bits)
  563. ;    pointer to XDPH in <DE>
  564. ;
  565. ;   return with an error code in <A>
  566. ;     A=0    no errors
  567. ;     A=1    non-recoverable error
  568. ;    A=2    disk write protected
  569. ;    A=FF    media change detected
  570. ;
  571.     DSEG
  572. read$154X:
  573.     call    get$drv$info
  574.     jm    mfm$rd
  575.     call    set$up$GCR        ; compute effective track and sector
  576. login$rd:
  577.     lda    vic$drv
  578.     mov    b,a
  579.     lda    fast            ; get fast flags
  580.     ana    b            ; isolate fast bit for this drive
  581.     jrnz    rd$fast            ; go handle fast drive
  582. rd$slow:
  583.     mvi    a,vicrd            ; read a sector of data (A=1)
  584.     call    dsk$fun            ; a=0 if no errors
  585.     jnz    test$error        ; check for disk error or media change
  586. ;
  587. ;
  588. ;
  589. buf$move:
  590.     xra    a            ; set direction to read
  591.     call    ?dkmov            ; go move buffer to DMA
  592.     lda    sect$cnt
  593.     ana    a
  594.     rz                ; a=0 means not read errors
  595.     call    set$up$next
  596.     jr    rd$slow
  597.  
  598.     page
  599. ;
  600. ;    A=drive type info
  601. ;
  602. mfm$rd:
  603.     call    set$up$MFM
  604.  
  605. rd$fast:
  606.     mvi    a,vic$rd$f
  607.     call    dsk$fun            ; go read the disk
  608.  
  609.     ani    0eh            ; mask off error bits
  610.     jrnz    test$error
  611.  
  612.     call    get$sector$size
  613.     inr    d
  614.     inr    e            ; adjust count for pre-decrement
  615.  
  616.     call    ?di$int
  617.     lxi    b,0DD00h        ; D2PRA
  618.     inp    a            ; get current clock polarity 
  619.     xri    10h            ; toggle clk$bit
  620.     outp    a            ; to have status sent (extra clock
  621.                     ; supplied by rd$1571$data for multi
  622.                     ; sector transfers)
  623.     lda    vic$count
  624. rd$multi$sect:
  625.     push    psw
  626.     push    d            ; save the sector size
  627.     call    rd$1571$data        ; read disk data to DMA address
  628.     pop    d
  629.  
  630.     lda    vic$data
  631.     ani    0eh
  632.     jrnz    test$error$pop        ; A=0 if no errors
  633.     pop    psw
  634.     dcr    a
  635.     jrnz    rd$multi$sect
  636.     ei
  637.     lda    sect$cnt
  638.     ana    a            ; any sectors left to read
  639.     jrz    done$rd$1571
  640.  
  641.     call    set$up$next
  642.     jr    rd$fast
  643.  
  644. done$rd$1571:
  645.     lxi    b,0DD00h        ;   D2PRA
  646.     inp    a
  647.     ani    not(10h)        ; set clk$bit hi
  648.     outp    a
  649.     xra    a            ; A=0 for no errors
  650.     ret
  651.  
  652.  
  653.     page
  654. ;
  655. ;
  656. ;
  657. write$154X:
  658.     call    get$drv$info
  659.     jm    mfm$wr
  660.     call    set$up$GCR
  661.     lda    vic$drv
  662.     mov    b,a
  663.     lda    fast            ; get fast flags
  664.     ana    b            ; isolate fast bit for this drive
  665.     jrnz    wr$fast$drive        ; go handle fast drive
  666. wr$slow:
  667.     mvi    a,-1            ; set direction to write
  668.     call    ?dkmov            ; go move DMA to buffer
  669.  
  670.     mvi    a,vicwr            ; write a sector of data
  671.     call    dsk$fun            ; a=0 if no errors
  672.     ani    0eh
  673.     jrnz    test$error
  674.     lda    sect$cnt
  675.     ana    a
  676.     rz
  677.     call    set$up$next
  678.     jr    wr$slow
  679.  
  680. test$error$pop:
  681.     pop    psw
  682. test$error:
  683.     ei
  684.     lda    vic$data
  685.     ani    0fh            ; check for disk error or media change
  686.     cpi    0bh            ; disk change ?
  687.     jrz    change$error
  688.     cpi    08h            ; test for write protect error
  689.     jrz    write$prot$error
  690.  
  691.     mvi    a,1            ;  get general error flag
  692.     ret
  693.  
  694. ;
  695. ;
  696. write$prot$error:
  697.     mvi    a,2
  698.     ret
  699.  
  700. ;
  701. ;
  702. change$error:
  703.     mvi    a,-1
  704.     ret
  705.  
  706.     page
  707. ;
  708. ;
  709. ;
  710. mfm$wr:
  711.     call    set$up$MFM
  712. wr$fast$drive:
  713.     mvi    a,vic$wr$f
  714.     call    dsk$fun            ; go send the write command
  715.  
  716.     call    get$sector$size        ; setup DMA adr and transfer count
  717.     lda    vic$count
  718. wr$multi$sect:
  719.     push    psw
  720.     push    d            ; save sector size
  721.     call    wr$1571$data        ; write data to disk from DMA address
  722.     pop    d
  723.     ani    0eh
  724.     jrnz    test$error$pop
  725.     pop    psw
  726.     dcr    a
  727.     jrnz    wr$multi$sect
  728.  
  729.     ei
  730.     lda    sect$cnt
  731.     ana    a
  732.     rz                ; return if no errors (A=0)
  733.     call    set$up$next
  734.     jr    wr$fast$drive
  735.  
  736.     page
  737. ;
  738. ;
  739. ;
  740. get$drv$info:
  741.     lhld    @dma
  742.     shld    local$dma
  743.     xchg
  744.     shld    DPH$pointer
  745.  
  746.     lda    @adrv            ; get drive number (0 to F)
  747.     ana    a
  748.     cz    drive$A$E
  749.     cpi    'E'-'A'            ; test if drive E
  750.     cz    drive$A$E
  751.     dcx    h            ; point at drive mask
  752.     dcx    h
  753.     mov    a,m            ; get drive mask
  754.     mov    b,a            ; save in B
  755.     sta    vic$drv            ; save vic drive # (values 1,2,4,8)
  756.  
  757.     inx    h            ; point at disk type
  758.     xra    a
  759.     sta    sect$cnt        ; clear the count
  760.     inr    a
  761.     sta    vic$count
  762.     mov    a,m            ; get disk type
  763.     ana    a
  764.     ret
  765.  
  766. ;
  767. ;    drive A and E share the same physical disk drive (unit 8)
  768. ;
  769. drive$A$E:
  770.     mov    b,a
  771.     lda    curdrv            ; get the current drive def
  772.     cmp    b            ; curdrv = requested drive ?
  773.     rz                ; yes, return
  774.                     ; no, tell the user to swap disk
  775.     push    h
  776.     push    d
  777.     push    b
  778. send$messg:
  779.     mov    a,b            ; get requested drive # to A
  780.     sta    curdrv            ; make this the current drive
  781.     adi    'A'            ; compute drive letter
  782.     sta    msg$drv
  783.  
  784.     RCALL    FR$bell            ; ring BELL to alert user
  785.     lxi    h,swap$msg$lng*256+buff$pos
  786.     lxi    d,swap$msg
  787.     call    disp$msg$DE$HL        ; disp and wait for CR
  788.  
  789.     mvi    a,vic$test
  790.     call    ?fun65
  791. ;    ani    0fh
  792. ;    cpi    0ch            ; not fast ERROR ?
  793. ;    jrz    exit$drv$A$E        ; yes, return that's not a problem
  794. ;    ani    0eh            ; other error type ?
  795. ;    jrnz    send$messg
  796. exit$drv$A$E:
  797.     pop    b
  798.     pop    d
  799.     pop    h
  800.     mov    a,b
  801.     ret
  802.  
  803. swap$msg:    db    'Insert Disk '
  804. msg$drv:    db    'X in Drive A'
  805.  
  806. swap$msg$lng    equ    $-swap$msg+2    ; +2 for leading and trailing spaces
  807.  
  808.     page
  809. ;    
  810. ;
  811. ;
  812. get$max$num$b:
  813.     lhld    DPH$pointer
  814.     lxi    b,42            ; offset to number of sectors on track
  815.     dad    b
  816.     mov    a,m            ; get number sectors/track/side
  817.     ani    1fh
  818.     mov    b,a
  819.     ret
  820. ;
  821. ;
  822. ;
  823. get$sector$size:
  824.     lhld    DPH$pointer
  825.     dcx    h
  826.     mov    a,m            ; disk type in B (bit 5,4 size info)
  827.     rrc                ; ..00 = 080h byte sectors
  828.     rrc                ; ..01 = 100h byte sectors
  829.     rrc                ; ..10 = 200h byte sectors
  830.     rrc                ; ..11 = 400h byte sectors
  831.     ani    3
  832.     jrz    set$128
  833.     jpo    not$3            ; jump if (A=) 01b or 10b
  834.     inr    a            ; make A = 4
  835. not$3:
  836.     mvi    e,0            ; set E to zero
  837.     mov    d,a            ; set sector size (1,2 or 4)
  838. get$DMA:
  839.     lhld    local$DMA        ; get the current DMA pointer
  840.     ret
  841.  
  842. set$128:
  843.     lxi    d,128
  844.     jr    get$DMA 
  845.  
  846.     page
  847. ;
  848. ;
  849. ;
  850.     DSEG
  851. set$up$GCR:
  852.     cpi    dsk$c128
  853.     jnz    tst$next
  854.  
  855.     mvi    a,4
  856.     sta    sect$cnt
  857.     lxi    h,sect$buffer
  858.     shld    sect$buf$ptr
  859.  
  860.     lhld    @trk            ; 1 K sector pointer 
  861.     dad    h
  862.     dad    h            ; make 256 byte pointer
  863. ;
  864. ;    build a list of tracks and sectors
  865. ;
  866. next$sect:
  867.     shld    @trk
  868.     RCALL    FR$trk$sect
  869.     lhld    vic$trk            ; get trk(L) and sector(H) to HL
  870.     xchg
  871.     lhld    sect$buf$ptr
  872.     mov    m,e
  873.     inx    h
  874.     mov    m,d
  875.     inx    h
  876.     shld    sect$buf$ptr
  877.     lhld    @trk
  878.     inr    l            ; update saved above at next$sect
  879.     mov    a,l
  880.     ani    3
  881.     jrnz    next$sect
  882. ;
  883. ;    check list of trk-sectors for number of sectors on this trk
  884. ; 
  885.     lxi    h,sect$buffer
  886.     shld    sect$buf$ptr
  887.     lda    vic$drv
  888.     mov    b,a
  889.     lda    fast
  890.     ana    b            ; drive type 1571
  891.     jrz    handle$1541        ; no, handle as 1541
  892.  
  893.     lda    sect$cnt        ; number of sectors to rd/wr
  894.     mov    b,a
  895.     inx    h
  896.     mov    a,m            ; get 1st sector #
  897.     sta    vic$sect
  898.     dcx    h
  899.     mov    a,m            ; get 1st track #
  900.     sta    vic$trk
  901.  
  902. try$next:
  903.     cmp    m            ; test for same trk #
  904.     jrnz    exit$no$match
  905.     inx    h
  906.     inx    h            ; advance to next trk
  907.     shld    sect$buf$ptr
  908.     djnz    try$next    
  909.  
  910. exit$no$match:
  911.     lda    sect$cnt        ; number of sectors to rd/wr
  912.     sub    b            ; remove number left
  913.                     ; (leaving number matched)
  914.     sta    vic$count        ; save number to read
  915.     mov    a,b            ; get remaining count
  916.     sta    sect$cnt        ; save remaining count
  917.     ret
  918.  
  919.  
  920. set$up$next:
  921.     lda    vic$count        ; get number of sectors read
  922.     lhld    local$DMA        ; get current DMA pointer
  923.     add    h            ; advance pointer by number of
  924.     mov    h,a            ; sectors read
  925.     shld    local$DMA
  926. handle$1541:
  927.     lhld    sect$buf$ptr
  928.     mov    a,m
  929.     sta    vic$trk
  930.     inx    h
  931.     mov    a,m
  932.     sta    vic$sect
  933.     inx    h
  934.     shld    sect$buf$ptr
  935.     lda    vic$drv
  936.     mov    b,a
  937.     lda    fast
  938.     ana    b
  939.     jrz    set$up$next$slow
  940.     lda    sect$cnt
  941.     sta    vic$count
  942.     xra    a            ; two reads max with fast drive
  943.     jr    set$up$next$exit
  944.  
  945. set$up$next$slow:
  946.     lda    sect$cnt
  947.     dcr    a
  948. set$up$next$exit:
  949.     sta    sect$cnt
  950.     ret
  951. ;
  952. ;
  953. ;
  954. tst$next:
  955.   if    use$1581
  956.     cpi    dsk$1581
  957.     jrz    c1581$adj
  958.   endif
  959. tst$c64:
  960.     mvi    b,dir$track    ; set the dir track number
  961.     cpi    dsk$c64        ; C64 type disk?
  962.     lda    @sect        ;   get sector # to set
  963.     jrz    set$up$c64    ; yes, go set up for C64 CP/M disk format
  964.                 ; no, set up as no type(direct addressing)
  965. ;
  966. ;    This format is for direct track and sector addressing 
  967. ;
  968. do$type$7:
  969.     mvi    b,255        ; no dir sector
  970. ;
  971. ;    this routine will adjust the track number if necessary.
  972. ;    The C64 CP/M disk has the C64 directory in the center
  973. ;    of the disk. This routine checks and adds one to the track
  974. ;    number if we have reached or passed the directory track. 
  975. ;
  976. set$up$c64:
  977.     sta    VIC$sect    ;
  978.     lda    @trk        ;
  979.     cmp    b        ; carry=1 if A < dir$track
  980.     cmc            ; add one if dir$track or more (carry not set)
  981.     aci    0        ; add the carry bit in
  982.     sta    vic$trk
  983.     ret
  984.  
  985.   if    use$1581
  986. ;
  987. ;******    adjust to read multi-512 byte sectors (system sees 1K sector size)
  988. ;
  989. c1581$adj:
  990.     mvi    a,2        ; 2 512 byte sectors equ 1 1K sector
  991.     sta    vic$count
  992.  
  993.     lda    @trk        ;
  994.     cpi    C1581$dir$trk*2    ; carry=1 if A < dir$track
  995.     cmc            ; add one if dir$track or more (carry not set)
  996.     aci    0        ; add the carry bit in
  997.     rar            ; track=@trk/2 ; carry set if odd
  998.     sta    vic$trk        ;
  999.  
  1000.     lda    @sect        ; sector # are 0 to 9 (10 sector/trk)
  1001.     mov    b,a        ;
  1002.     jrnc    bottom$1581    ;
  1003.     adi    80h        ; set top of 1581
  1004. bottom$1581:
  1005.     add    b        ; make 0 to 8
  1006.     inr    a        ; adjust to 1 to 9 (odd numbers only)
  1007.     sta    VIC$sect    ;
  1008.     ret            ;
  1009.  
  1010.   endif
  1011.  
  1012.  
  1013.     page
  1014. ;
  1015. ;    A=dsk$info on entry
  1016. ;
  1017. set$up$MFM:
  1018.     mvi    d,0        ; D=side # (0)
  1019.     mov    e,a        ; save dsk$info in E
  1020.     ani    TypeX        ; look at Type0 to Type7
  1021.     jrz    do$type$0    ;
  1022.     cpi    Type2
  1023.     lda    @trk        ; used by Type1, Type2 and Type3
  1024.     jrz    do$type$2
  1025.     jrc    do$type$1
  1026.  
  1027. ;    cpi    Type6
  1028. ;    jrz    do$type$6
  1029. ;    jnc    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  1030.  
  1031.     cpi    Type7
  1032.     jz    do$type$7    ; MSB of sector(byte) set for 2nd side of disk
  1033. ;
  1034. ;    only types 0 to 2 and 7 are currenty defined
  1035. ;        Type3 to Type6 will do Type2
  1036. ;do$type$3:
  1037. ;do$type$6:
  1038.  
  1039. do$type$2:
  1040.     mov    b,a        ; save a copy in B
  1041.     sui    40
  1042.     jrc    do$type$0    ; jump if still on side 0
  1043.     mvi    a,79        ; on back side count 39,38,37,...,0
  1044.     sub    b
  1045. set$trk:
  1046.     mvi    d,80h        ; D=side # (1)
  1047.     sta    @trk
  1048.     jr    do$type$0
  1049.  
  1050.     page
  1051. ;
  1052. ;    divide the track number by two and if Head=1
  1053. ;        add #sect/side to @sect
  1054. ;
  1055. do$type$1:
  1056.     cmc            ; carry was set clear it
  1057.     rar            ; divide track by 2 (carry gets LSB)
  1058.     sta    @trk
  1059.     jrnc    do$type$0
  1060.     call    get$max$num$b    ; HL and C changed
  1061.     lda    @sect
  1062.     add    b
  1063.     sta    @sect
  1064.  
  1065. do$type$0:
  1066.     lda    @trk
  1067.     sta    vic$trk
  1068.     call    get$max$num$b    ; B=number of sectors per track per side
  1069.     lda    @sect        ; ..HL and C changed
  1070.     cmp    b
  1071.     jrc    is$side$0
  1072.     mvi    d,80h        ; D=side # (1)
  1073.     bit    C1$bit,e    ; dsk$info in E
  1074.                 ; sector numbering continues on side 1 ?
  1075.     jrnz    is$side$0    ; yes, do not remove side one bias
  1076.     sub    b        ; no, remove side one bias
  1077. is$side$0:
  1078.     mov    c,a        ; hold @sect in C    
  1079.     mov    a,e        ; get dsk$info to A
  1080.     ani    S1        ; A=Starting  sector number (0 or 1)
  1081.     add    c        ; add back @sect
  1082.     ora    d        ; add in the side bit
  1083.     sta    vic$sect
  1084.     ret
  1085.  
  1086.     page
  1087. ;
  1088. ;    input:
  1089. ;        DE = number bytes to read
  1090. ;        HL = DMA address
  1091. ;
  1092.     CSEG
  1093. rd$1571$data:
  1094.     lda    @dbnk            ; get the disk DMA bank
  1095.     call    ?bank            ; set it
  1096.  
  1097.     lxi    b,0DC0Dh        ; D1ICR
  1098. rd$1571$stat$wait:
  1099.     inp    a
  1100.     ani    8            ; data ready bit set?
  1101.     jrz    rd$1571$stat$wait    ; no, loop
  1102.  
  1103.     mvi    c,0ch            ; D1SDR
  1104.     inp    a            ; read the status byte
  1105.     sta    vic$data        ; save it
  1106.     ani    0eh            ; any errors ?
  1107.     jrnz    rd$1571$exit        ; yes, exit
  1108.  
  1109.     lxi    b,0DD00h
  1110.     inp    a            ; get current clock polarity
  1111.  
  1112. rd$1571$next:
  1113.     lxi    b,0DD00h        ; D2PRA
  1114.     xri    10h            ; toggle clk$bit
  1115.     outp    a            ; clock the 1571 for a byte
  1116.  
  1117.     dcr    e            ; DE=count
  1118.     jnz    rd$1571$more        ; leave as normal jump to keep
  1119.     dcr    d            ; the transfer speed at it's max
  1120.     jrz    rd$1571$exit        ; ...
  1121.  
  1122. ;
  1123. rd$1571$more:
  1124.     dcr    b
  1125. rd$1571$wait:
  1126.     mvi    c,0dh            ; D1ICR (DC0Dh)
  1127.     inp    c
  1128.     bit    3,c
  1129.     jz    rd$1571$wait
  1130.     mvi    c,0ch            ; D1SDR
  1131.     ini                ; (hl) <- (bc) ; hl <- hl+1 ; b <- b-1
  1132.     jmp    rd$1571$next
  1133.  
  1134.  
  1135. rd$1571$exit:
  1136.     sta    bank$0            ; restore current mem config
  1137.     ret
  1138.  
  1139.     page
  1140.  
  1141. clk$in    equ    40h
  1142. ;
  1143. ;    input:
  1144. ;        DE = number of bytes to write
  1145. ;        HL = DMA address
  1146. ;
  1147. wr$1571$data:
  1148.     call    ?di$int
  1149. ; do spout inline
  1150.     lxi    b,mode$reg
  1151.     mvi    a,fast$wr$en
  1152.     sta    io$0
  1153.     outp    a            ; set data direction to output
  1154.     sta    bank$0
  1155.  
  1156.     lxi    b,0dc05h        ; low (D1T1h)
  1157.     xra    a
  1158.     outp    a
  1159.     dcr    c            ; low(D1T1l)
  1160.     mvi    a,3            ; clk = osc/3
  1161.     outp    a            ;
  1162.  
  1163.     mvi    c,0eh            ; D1CRA
  1164.     inp    a
  1165.     ani    80h
  1166.     ori    55h
  1167.     outp    a
  1168.     dcr    c            ; D1ICR
  1169.     inp    a
  1170.  
  1171.     lda    @dbnk            ; get the disk DMA bank
  1172.     call    ?bank            ; set it
  1173.  
  1174.     mvi    a,clk$in
  1175.     sta    cur$clk
  1176.  
  1177.     page
  1178. ;
  1179. ;
  1180. clk$wait:
  1181.     lxi    b,0dd00h        ; D2PRA
  1182.     inp    a
  1183.     inp    c            ; debounce
  1184.     cmp    c
  1185.     jrnz    clk$wait
  1186.  
  1187.     lda    cur$clk            ; get old clk value
  1188.     xra    c            ; check if changed 
  1189.     ani    clk$in            ; (only clock in bit)
  1190.     jrz    clk$wait        ; loop if not
  1191.  
  1192.     mov    a,c            ; 
  1193.     sta    cur$clk            ; make this the current clk value
  1194.     lxi    b,0dc0ch        ; D1SDR
  1195.     mov    a,m
  1196.     outp    a            ; send character to drive
  1197.     inx    h            ; advance pointer
  1198.     dcx    d            ; dec the char count
  1199.  
  1200.     inr    c            ; D1ICR
  1201. send$wait:
  1202.     inp    a
  1203.     ani    8
  1204.     jz    send$wait
  1205.  
  1206.     mov    a,d
  1207.     ora    e
  1208.     jnz    clk$wait        ; go send the next byte
  1209.  
  1210. ; do spin
  1211.     lxi    b,0DC0Eh        ; D1CRA
  1212.     inp    a
  1213.     ani    80h
  1214.     ori    8
  1215.     outp    a
  1216.     lxi    b,mode$reg
  1217.     mvi    a,fast$rd$en
  1218.     sta    io$0            ; enable the MMU
  1219.     outp    a            ; set data direction to input
  1220.     sta    bank$0            ; disable MMU
  1221. ; spin done
  1222.  
  1223.     page
  1224.  
  1225.     lxi    b,0DC0Dh        ; D1ICR
  1226.     inp    a            ; clear data pending flag
  1227.  
  1228.     lxi    b,0DD00h        ; D2PRA
  1229.     inp    a
  1230.     ori    10h            ; set clk$bit low (hardware inverted)
  1231.     outp    a            ; 
  1232.  
  1233.     lxi    b,0DC0Dh        ; D1ICR
  1234. wait$status:
  1235.     inp    a
  1236.     ani    8
  1237.     jrz    wait$status
  1238.  
  1239.     lxi    b,0DC0Ch        ; D1SDR
  1240.     inp    d
  1241.  
  1242.     lxi    b,0DD00h        ; D2PRA
  1243.     inp    a
  1244.     ani    not(10h)        ; set clk$bit hi (hardware inverted)
  1245.     outp    a            ; 
  1246.  
  1247.     mov    a,d            ; recover the status byte
  1248.     sta    vic$data
  1249.  
  1250.     ei
  1251.     ret
  1252.  
  1253.     page
  1254. ;
  1255. ;    This routine is used to move a sector of data
  1256. ;     to/from the sector buffer and the DMA pointer.
  1257. ;         A=0 for buffer to DMA  (disk read)
  1258. ;         A<>0 for DMA to buffer (disk write)
  1259. ;
  1260.     CSEG
  1261. ?dkmov:
  1262.     lhld    local$DMA    ; current DMA adr
  1263.     lxi    d,@buffer    ; location of disk read/write buffer
  1264.     lxi    b,256        ; sector size
  1265. ;
  1266. ;
  1267. dk$cont:
  1268.     ora    a
  1269.     jrnz    dsk$read    ; swap pointer for read
  1270.     xchg
  1271. ;
  1272. ;
  1273. dsk$read:
  1274.     lda    @dbnk        ; get the disk bank
  1275.     call    ?bank
  1276.     ldir            ; do the data move
  1277.     sta    bank$0        ; current bank will ALWAYS be 0
  1278.     ret
  1279.  
  1280. ;
  1281. ;
  1282. ;
  1283.     DSEG
  1284. dsk$fun:
  1285.     sta    vic$cmd
  1286.     lda    stat$enable
  1287.     ani    1            ; display of disk info enabled?
  1288.     cnz    disp$dsk$info        ; yes, go display disk info
  1289.     jmp    ?fun65+3        ; go do the function
  1290.  
  1291.     page
  1292. ;
  1293. ;
  1294. ;
  1295.     DSEG
  1296. ?dskst:
  1297. disp$dsk$info:
  1298.     mvi    a,72            ; r/w in col 72 (col 0-79)
  1299.     sta    offset
  1300.     lda    vic$cmd
  1301.     mvi    b,'R'
  1302.     dcr    a            ; ?1 normal$rd
  1303.     jrz    out$cmd$rd
  1304.     dcr    a            ; ?2 normal$wr
  1305.     jrz    out$cmd$wr
  1306.     dcr    a            ; ?3 fast$rd
  1307.     jrz    out$cmd$rd
  1308.     dcr    a            ; ?4 fast$wr
  1309.     rnz
  1310. out$cmd$wr:
  1311.     mvi    b,'W'
  1312. out$cmd$rd:
  1313.     call    disp$B
  1314.     call    disp$space
  1315.     mvi    b,'A'-1
  1316.     lda    vic$drv
  1317. next$drv:
  1318.     inr    b
  1319.     rrc
  1320.     jrnc    next$drv
  1321.  
  1322.     call    disp$B
  1323.     lda    vic$trk
  1324.     call    disp$dec
  1325.     lda    vic$sect
  1326.     ani    80h
  1327.     cz    disp$space
  1328.     mvi    b,'-'
  1329.     cnz    disp$B
  1330.     lda    vic$sect    
  1331.     ani    7fh
  1332.  
  1333.     page
  1334. ;
  1335. ;
  1336. ;
  1337. disp$dec:
  1338.     mvi    b,'0'-1
  1339.  
  1340. conv$loop:
  1341.     inr    b
  1342.     sui    10
  1343.     jrnc    conv$loop
  1344.  
  1345.     adi    '0'+10
  1346.     push    psw
  1347.     call    disp$B
  1348.     pop    psw
  1349. disp$A:
  1350.     mov    b,a
  1351. disp$B:
  1352.     lxi    h,@st40-72+40-8
  1353.     lda    offset
  1354.     mov    e,a
  1355.     mvi    d,0
  1356.     dad    d            ; add the offset
  1357.     mov    m,b            ; save on 40 col display
  1358.  
  1359.     mov    a,e
  1360.     mov    c,a            ; col # in C
  1361.     inr    a
  1362.     sta    offset            ; advance cursor position
  1363.     xra    a            ; no attribute to write
  1364.     call    ?stat
  1365.  
  1366.     lxi    h,@st40
  1367.     lxi    d,vic$screen+40*24    ; update 40 column screen
  1368.     lxi    b,40
  1369.     ldir
  1370.     xra    a
  1371.     ret
  1372.  
  1373. disp$space:
  1374.     mvi    b,' '
  1375.     jr    disp$B
  1376.  
  1377.     page
  1378. ;
  1379. ; Extended Disk Parameter Headers (XDPHs)
  1380. ;
  1381.     CSEG            ; place tables in common
  1382. ;
  1383. ;    1st disk drive on the system
  1384. ;
  1385.     dw    write$154X
  1386.     dw    read$154X
  1387.     dw    login$154X
  1388.     dw    init$154X
  1389.     db    1        ; bit 0 set (drive 0)
  1390.     db    dsk$c128    ; format type byte
  1391. cmdsk0:    
  1392.     dph    0,dpb$0
  1393.  
  1394. dpb$0:
  1395.     dpb    1024,5,159,2048,128,0
  1396.     db    0        ; max sector number and lock flag
  1397.     dw    0        ; MFM table pointer
  1398.  
  1399.     page
  1400. ;
  1401. ;    2nd disk Drive on the system
  1402. ;
  1403.     dw    write$154X
  1404.     dw    read$154X
  1405.     dw    login$154X
  1406.     dw    init$154X
  1407.     db    2        ; bit 1 set (drive 1)
  1408.     db    dsk$c128    ; format type byte 
  1409. cmdsk1:
  1410.     dph    0,dpb$1
  1411.  
  1412. dpb$1:
  1413.     dpb    1024,5,159,2048,128,0
  1414.     db    0        ; max sector number and lock flag
  1415.     dw    0        ; MFM table pointer
  1416.  
  1417.     page
  1418. ;
  1419. ;    3rd disk drive on the system
  1420. ;
  1421.     dw    write$154X
  1422.     dw    read$154X
  1423.     dw    login$154X
  1424.     dw    init$154X
  1425.     db    4        ; bit 2 set (drive 2)
  1426.     db    dsk$c128    ; format type byte
  1427. cmdsk2:    
  1428.     dph    0,dpb$2
  1429.  
  1430. dpb$2:
  1431.     dpb    1024,5,159,2048,128,0
  1432.     db    0        ; max sector number and lock flag
  1433.     dw    0        ; MFM table pointer
  1434.  
  1435.     page
  1436. ;
  1437. ;    4th disk drive on the system
  1438. ;
  1439.     dw    write$154X
  1440.     dw    read$154X
  1441.     dw    login$154X
  1442.     dw    init$154X
  1443.     db    8        ; bit 3 set (drive 3)
  1444.     db    dsk$c128    ; format type byte 
  1445. cmdsk3:
  1446.     dph    0,dpb$3
  1447.  
  1448. dpb$3:
  1449.     dpb    1024,5,159,2048,128,0
  1450.     db    0        ; max sector number and lock flag
  1451.     dw    0        ; MFM table pointer
  1452.  
  1453.     page
  1454. ;
  1455. ;    Drive E: shared with 1st drive (A:)
  1456. ;
  1457.     dw    write$154X
  1458.     dw    read$154X
  1459.     dw    login$154X
  1460.     dw    init$154X
  1461.     db    1        ; bit 0 set (drive 0)
  1462.     db    dsk$c128    ; format type byte 
  1463. cmdsk4:
  1464.     dph    0,dpb$4
  1465.  
  1466. dpb$4:
  1467.     dpb    1024,5,159,2048,128,0
  1468.     db    0        ; max sector number and lock flag
  1469.     dw    0        ; MFM table pointer
  1470.  
  1471.     page
  1472. ;
  1473. ;    NOTE: The blocking factor for all of these formats is
  1474. ;        1K (2K for double sided), thus the fractional
  1475. ;        parts are unusable by CP/M.  They can be accessed
  1476. ;        by absolute sector addressing.
  1477. ;
  1478. ;    NOTE: 1571 and 1541 disk drives use track numbers
  1479. ;        of 1 to 35 and sector numbers of 0 to nn
  1480.  
  1481. ;
  1482. ;        The method used to access the full disk
  1483. ;        is to tell the system that there is 1 sector
  1484. ;        per track and then to use the track # as an
  1485. ;        absolute sector address and do conversion in BIOS.
  1486. ;
  1487. ; 
  1488. ; DPB FOR C128 CP/M 3.0 disk        ( 170K, 34K larger then C64 CP/M)
  1489. ;    256 byte sectors        ( 170.75K )
  1490. ;    1 sectors/track
  1491. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1492. ;    680 tracks/disk (usable, 683 real)
  1493. ;        35 physical tracks (0 to 34)
  1494. ;    1K allocation blocks
  1495. ;    64 directory entries
  1496. ;    track offset of 0
  1497. ;
  1498.     DSEG        ; these tables are moved to common when used
  1499. dpb$c128$SS:        ; (170 allocation units)
  1500.     dpb    1024,1,170,1024,64,0
  1501.  
  1502.     page
  1503. ;
  1504. ; DPB FOR C128 CP/M 3.0 double sided disk    ( 340K )
  1505. ;    1024 byte sectors (phy=256)        ( 341.5K )    
  1506. ;    1 sectors/track
  1507. ;        up to 21 physical sectors (0 to 16,17,18 or 20)
  1508. ;    340 tracks/disk (usable, 1366 real)
  1509. ;        70 physical tracks (0 to 34 side 0, 35 to 69 side 1)
  1510. ;    2K allocation units
  1511. ;    128 directory entrys
  1512. ;    track offset of 0
  1513. ;
  1514. dpb$c128$DS:        ; (170 allocation units)
  1515.     dpb    1024,1,340,2048,128,0
  1516.  
  1517.     page
  1518. ;
  1519. ; DPB FOR C64 CP/M 2.2 disk --             ( 136K )
  1520. ;    256 byte sectors
  1521. ;    17 sectors / tracks    (sector numbering 0-16)
  1522. ;        sector 18 to n on the outer tracks are unused
  1523. ;    34 tracks / disk
  1524. ;        tracks track 2 to 16    (track numbering 0-34)
  1525. ;        track 17 is the C128 directory track (not counted)
  1526. ;        track 19 to 34
  1527. ;    1K allocation blocks
  1528. ;    64 directory entrys
  1529. ;    track offset of 3 (1st two tracks used for CP/M 2.2 boot) plus
  1530. ;    one sector to adjust for sector numbering of 1 to 35 (not 0 to 34)
  1531. ;
  1532. dpb$c64$cpm:        ; (144 allocation units)
  1533.     dpb    256,17,34,1024,64,3
  1534.                 
  1535.     page
  1536. ;
  1537. ; DPB FOR C128 CP/M 3.0 C1581 DSDD (3.5")    (    K )
  1538. ;    512 byte sectors            ( 720K )
  1539. ;    10 sectors/track
  1540. ;    159 tracks/disk
  1541. ;        160 physical tracks 80 on top, 79 on bottom, 1 used for
  1542. ;        BAM and disk directory (1581 DOS) (10 sectors per track)
  1543. ;    2K allocation units
  1544. ;    128 directory entrys (2 allocation units)
  1545. ;
  1546.   if    use$1581
  1547. dpb$1581:        ; (xxx allocation units)
  1548.     dpb    1024,5,159,2048,128,0
  1549.   endif
  1550.  
  1551.     page
  1552. ;
  1553.     DSEG
  1554. MFM$table:
  1555.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1556.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1557.     dw    0            ; start on track 2 sect 1 (2 alc)
  1558.     dpb    256,32,40,2048,128,2    ; sect# 1 to 16
  1559.     db    16            ; (top and bottom numbered the same)
  1560.     db    'Epson QX10'        ;1 Epson QX10
  1561.                     ; 160 allocation units
  1562.  
  1563.  
  1564.  
  1565.  
  1566.     db    80h+S512*2+(10*2-8)+1    ; 512 byte sect, 10 sect/trk
  1567. ;    db    S256*2            ; track 0 is 256 bytes/sector
  1568.     db    MFM+S512+Type0+C0+S1    ;    DSDD
  1569.     dw    0            ; start on track 2 sect 1 (2 alc)
  1570.     dpb    512,20,40,2048,128,2    ; sect# 1 to 10
  1571.     db    10            ; (top and bottom numbered the same)
  1572.     db    'Epson QX10'        ;2
  1573.                     ; 200 allocation units
  1574.  
  1575.     page
  1576.  
  1577.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1578.     db    MFM+S512+Type2+C0+S1    ;     SSDD
  1579.     dw    0            ; start on track 1 sector 1 (2 alc)
  1580.     dpb    512,8,40,1024,64,1    ; sect# 1 to 8
  1581.     db    8            ;
  1582.     db    ' IBM-8 SS '        ;3
  1583.                     ; 160 allocation units
  1584.  
  1585.  
  1586.  
  1587.  
  1588.     db    S512*2+(8*2-8)+1    ; 512 byte sect 8 sect/trk
  1589.     db    MFM+S512+Type2+C0+S1    ;     DSDD
  1590.     dw    0            ; start on track 1 sector 1 (1 alc)
  1591.     dpb    512,8,80,2048,64,1    ; sect# 1 to 8
  1592.     db    8            ; (top and bottom numbered the same)
  1593.     db    ' IBM-8 DS '        ;4
  1594.                     ; 160 allocation units
  1595.  
  1596.     page
  1597.  
  1598.     db    S512*2+(10*2-8)+0    ; 512 byte sector, 10 sect/trk
  1599.     db    MFM+S512+Type1+C1+S0    ;    DSDD
  1600.     dw    0            ; start on track 0 sector 10 (2 alc)
  1601.     dpb    512,10,80,2048,128,1    ; sect# 0 to 9 on top (even tracks)
  1602.     db    10            ; sect# 10 to 19 on bottom (odd tracks)
  1603.     db    'KayPro IV '        ;5
  1604.                     ; 200 allocation units
  1605.  
  1606.  
  1607.  
  1608.  
  1609.     db    S512*2+(10*2-8)+0    ; 512 byte sect, 10 sect/trk
  1610.     db    MFM+S512+Type0+C1+S0    ;     SSDD
  1611.     dw    0            ; start on track 1 sector 0 (4 alc)
  1612.     dpb    512,10,40,1024,64,1    ; sect# 0 to 9 
  1613.     db    10            ;
  1614.     db    'KayPro II '        ;6
  1615.                     ; 200 allocation units
  1616.  
  1617.     page
  1618.  
  1619.     db    S1024*2+(5*2-8)+1    ; 1024 byte sect, 5 sect/trk
  1620.     db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1621.     dw    0            ; start on track 3 sector 1 (2 alc)
  1622.     dpb    1024,5,40,1024,64,3    ; sect# 1 to 5
  1623.     db    5            ;
  1624.     db    'Osborne DD'        ;7
  1625.                     ; 200 allocation units
  1626.  
  1627.  
  1628.     db    S512*2+(9*2-8)+1    ; 512 byte sect 9 sect/track (uses 8)
  1629.     db    MFM+S512+Type1+C0+S1    ;     DSDD
  1630.     dw    0            ; start on trk 0, sect 1, hd 1 (1 alc)
  1631.     dpb    512,8,80,2048,64,1    ; sect# 1 to 9
  1632.     db    8            ; (top and bottom numbered the same)
  1633.     db    '  Slicer  '        ;8
  1634.                     ; 160 allocation units
  1635.  
  1636.     page
  1637.  
  1638.     db    S256*2+(16*2-8)+1    ; 256 byte sect, 16 sect/trk
  1639.     db    MFM+S256+Type0+C0+S1    ;     DSDD
  1640.     dw    0            ; start on track 4 sect 1 (2 alc)
  1641.     dpb    256,32,40,2048,128,4    ; sect# 1 to 16
  1642.     db    16            ; (top and bottom numbered the same)
  1643.     db    'Epson Euro'        ;9 Epson European (MFCP/M ?)
  1644.                     ; 160 allocation units
  1645.  
  1646.  
  1647.  
  1648.     db    -1
  1649.     db    MFM            ; 
  1650.     dw    0            ; 
  1651.     dpb    512,20,40,2048,128,2    ; 
  1652.     db    8            ;
  1653.     db    '   None   '        ;10
  1654.  
  1655.     page
  1656.  
  1657.     db    -1
  1658.     db    MFM            ; 
  1659.     dw    0            ; 
  1660.     dpb    512,20,40,2048,128,2    ; 
  1661.     db    8            ;
  1662.     db    '   None   '        ;11
  1663.  
  1664.     db    -1
  1665.     db    MFM            ; 
  1666.     dw    0            ; 
  1667.     dpb    512,20,40,2048,128,2    ; 
  1668.     db    8            ;
  1669.     db    '   None   '        ;12
  1670.  
  1671.     page
  1672.  
  1673.     db    -1
  1674.     db    MFM            ; 
  1675.     dw    0            ; 
  1676.     dpb    512,20,40,2048,128,2    ; 
  1677.     db    8            ;
  1678.     db    '   None   '        ;13
  1679.  
  1680.     db    -1
  1681.     db    MFM            ; 
  1682.     dw    0            ; 
  1683.     dpb    512,20,40,2048,128,2    ; 
  1684.     db    8            ;
  1685.     db    '   None   '        ;14
  1686.  
  1687.     page
  1688.  
  1689.     db    -1
  1690.     db    MFM            ; 
  1691.     dw    0            ; 
  1692.     dpb    512,20,40,2048,128,2    ; 
  1693.     db    8            ;
  1694.     db    '   None   '        ;15
  1695.  
  1696.     db    -1
  1697.     db    MFM            ; 
  1698.     dw    0            ; 
  1699.     dpb    512,20,40,2048,128,2    ; 
  1700.     db    8            ;
  1701.     db    '   None   '        ;16
  1702.  
  1703.  
  1704.     page
  1705. ;
  1706. ;    not functional yet
  1707. ;
  1708.  
  1709. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect 5 sect/track
  1710. ;    db    MFM+S1024+Type0+C0+S1    ;     SSDD
  1711. ;    dw    0            ; start on trk 2, sect 1 (2 alc)
  1712. ;    dpb    1024,5,40,2048,128,2    ; sect# 1 to 5
  1713. ;    db    5            ;
  1714. ;    db    'Morrow MD2'        ; 
  1715.  
  1716.  
  1717.  
  1718.  
  1719.  
  1720. ;    db    S1024*2+(5*2-8)+1    ; 1024 byte sect  5 sect/trk
  1721. ;    db    MFM+S1024+Type0+C0+S1    ;     DSDD
  1722. ;    dw    0            ; start on trk 1, sect 1, hd 0 (3 alc)
  1723. ;    dpb    1024,10,40,2048,192,1    ; sect# 1 to 5
  1724. ;    db    5            ;
  1725. ;    db    'Morrow MD3'        ; 
  1726.  
  1727.  
  1728. MFM$tbl$entries    equ    ($-MFM$table)/32
  1729.  
  1730.     db    -1            ; mark end of table
  1731.     db    -1
  1732.  
  1733.     page
  1734.  
  1735.     cseg
  1736. cur$clk:    ds    1
  1737.  
  1738.     dseg
  1739. lock$flag    ds    1
  1740. last$match    ds    2
  1741. window$info:    ds    2
  1742.  
  1743. dsk$window    equ    12
  1744.  
  1745. no$dsk$msg:
  1746.         ;1234567890
  1747.     db    ' Missing  ' 
  1748.  
  1749.  
  1750. MFM$match$tbl:
  1751.     ds    2*MFM$tbl$entries    ; MFM$count MUST follow this parm
  1752. MFM$count:
  1753.     ds    1            ; MFM$offset MUST follow this parm
  1754. MFM$offset:
  1755.     ds    1
  1756.  
  1757. MFM$cur$ptr:
  1758.     ds    2
  1759.  
  1760. DPH$pointer:
  1761.     ds    2
  1762.  
  1763. sect$cnt:
  1764.     ds    1
  1765. sect$buf$ptr:
  1766.     ds    2
  1767. sect$buffer:
  1768.     ds    4*2
  1769.  
  1770. local$DMA:
  1771.     ds    2
  1772.  
  1773. status$atr    equ    0
  1774. offset:        db    0
  1775.  
  1776.     end
  1777.  
  1778.